Examples: Open method (NotesStream - LotusScript®)

This example gets information on the normal files in a directory by opening each file as a stream. The agent reuses the same NotesStream object by opening and closing it for each file.

Sub Initialize
  Dim session As New NotesSession
  Dim stream As NotesStream
  Set stream = session.CreateStream
  files& = 0
  bytes& = 0
  directory$ = "C:\StreamFiles"
  Chdir directory$
  file$ = Dir$("*.*")
  While file$ <> ""
    If Not stream.Open(path$ & file$) Then
      Messagebox file$,, "Open failed"
      Exit Sub
    End If
    files& = files& + 1
    bytes& = bytes& + stream.Bytes
    Call stream.Close
    file$ = Dir$()
  Wend
  Messagebox "Number of files = " & files& & Chr(13) & _
  "Total bytes = " & bytes&,, "Normal files in " & directory$
End Sub

This agent opens a file as a stream for reading. The user specifies the name of the file but not the extension which is .txt. The agent uses the file name for the content of the Subject item.

Sub Initialize
  Dim session As NotesSession
  Dim db As NotesDatabase
  Dim dc As NotesDocumentCollection
  Dim doc As NotesDocument
  Dim stream As NotesStream
  Dim pathname As String
  pathname = "c:\StreamFiles\"
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set dc = db.UnprocessedDocuments
  Set doc = dc.GetFirstDocument
  Set stream = session.CreateStream
  REM Use name of text file as subject
  subject$ = Inputbox$("Name of file")
  pathname = pathname & subject$ & ".txt"
  If Not stream.Open(pathname, "ASCII") Then
    Messagebox pathname,, "Open failed"
    Exit Sub
  End If
  If stream.Bytes = 0 Then
    Messagebox pathname,, "File has no content"
    Exit Sub
  End If
  Set doc = New NotesDocument(db)
  Call doc.ReplaceItemValue("Form", "Main Topic")
  Call doc.ReplaceItemValue("Subject", subject$)
  Call doc.ReplaceItemValue("Body", stream.ReadText())
  Call stream.Close
  Call doc.save(True, True)
End Sub

This agent opens a file for writing.

Sub Initialize
  Dim session As NotesSession
  Dim db As NotesDatabase
  Dim dc As NotesDocumentCollection
  Dim doc As NotesDocument
  Dim stream As NotesStream
  Dim pathname As String
  pathname = "c:\StreamFiles\"
  Set session = New NotesSession
  Set db = session.CurrentDatabase
  Set dc = db.UnprocessedDocuments
  Set doc = dc.GetFirstDocument
  Set stream = session.CreateStream
  pathname = pathname & doc.GetItemValue("Subject")(0) & _
  ".txt"
  If Not stream.Open(pathname, "ASCII") Then
    Messagebox pathname,, "Open failed"
    Exit Sub
  End If
  If stream.Bytes <> 0 Then
    Messagebox pathname,, _
    "File already exists and has content"
    Exit Sub
  End If
  Call stream.WriteText(doc.GetItemValue("Body")(0))
  Call stream.Close
End Sub